Whither?

Example 321

★

A door whose description says where it leads; and which automatically understands references such as "the west door" and "the east door" depending on which direction it leads from the location.

Here we expand on the simple examples When? and Whence?; this time we want the player to be able to refer to doors by their directions, as in "the west door" when the door in question does in fact lead west.

Play/modify in Borogove

"Whither?"

The temporal vortex is an open door. It is west of Yesterday and east of Today.

The initial appearance of a door is usually "Nearby [an item described] leads [if the other side of the item described is visited][direction of the item described from the location] to [other side of the item described][otherwise][direction of the item described from the location][end if]."

Direction-relevance relates a door (called X) to a direction (called Y) when the direction of X from the location is Y. The verb to be directionally-relevant to means the direction-relevance relation.

Understand "[something related by direction-relevance] door" as a door.

As an added touch, we respond also to the case where the player postulates a door in some direction when there is no such thing at the moment:

Rule for printing a parser error when the player's command includes "[non-door direction] door":
   say "There is no door in that direction." instead.
 
Definition: a direction (called direction D) is non-door:
   let the target be the room-or-door direction D from the location;
   if the target is a door:
      no;
   yes;
 
Test me with "examine west door / x east door / w / x w door / x e door / tie me to the west door / tie the west door to me / push the west door east / push the east door west".

Test me with "examine west door / x east door / w / x w door / x e door / tie me to the west door / tie the west door to me / push the west door east / push the east door west".

Yesterday
Nearby a temporal vortex leads west.

>(Testing.)

>[1] examine west door
You see nothing special about the temporal vortex.

>[2] x east door
There is no door in that direction.

>[3] w

Today
Nearby a temporal vortex leads east to Yesterday.

>[4] x w door
There is no door in that direction.

>[5] x e door
You see nothing special about the temporal vortex.

>[6] tie me to the west door
There is no door in that direction.

>[7] tie the west door to me
There is no door in that direction.

>[8] push the west door east
There is no door in that direction.

>[9] push the east door west
The temporal vortex cannot be pushed from place to place.