Ways Out
Example 350
★A not-uncommon device in games with large maps is a list of available exits printed in the status bar. We might do this so:
"Ways Out"
When play begins:
now left hand status line is "Exits: [exit list]";
now right hand status line is "[location]".
To say exit list:
let place be location;
repeat with way running through directions:
let place be the room way from the location;
if place is a room, say " [way]".
We may find that printing out full directions makes the status line unpleasantly crowded. Fortunately, it isn't hard to provide a set of abbreviations to use in this context:
Rule for printing the name of a direction (called the way) while constructing the status line:
choose row with a heading of the way in the Table of Abbreviation;
say "[shortcut entry]".
Table of Abbreviation
| heading | shortcut |
| north | "N" |
| northeast | "NE" |
| northwest | "NW" |
| east | "E" |
| southeast | "SE" |
| south | "S" |
| southwest | "SW" |
| west | "W" |
| up | "U" |
| down | "D" |
| inside | "IN" |
| outside | "OUT" |
Dome is a room. North of Dome is North Chapel. South of the Dome is South Chapel. West of the Dome is Western End. Quiet Corner is northwest of the Dome, north of Western End, and west of North Chapel. Loud Corner is east of North Chapel, northeast of Dome, and north of Eastern End. Eastern End is north of Dim Corner and east of Dome. Dim Corner is southeast of Dome and east of South Chapel. Ruined Corner is southwest of Dome, west of South Chapel, and south of Western End.
The church door is east of Eastern End and west of the Courtyard. The church door is a door.
Test me with "w / n / e / e / s / e".
Test me with "w / n / e / e / s / e".
Dome
>(Testing.)
>[1] w
Western End
>[2] n
Quiet Corner
>[3] e
North Chapel
>[4] e
Loud Corner
>[5] s
Eastern End
You can see a church door here.
>[6] e
(first opening the church door)
Courtyard
You can see a church door here.
>(Testing.)
>[1] w
Western End
>[2] n
Quiet Corner
>[3] e
North Chapel
>[4] e
Loud Corner
>[5] s
Eastern End
You can see a church door here.
>[6] e
(first opening the church door)
Courtyard
You can see a church door here.
Everywhere else, the names of directions will still be printed out in full in the usual way.